subscriptions
Summary
Details
Do not create more than 2000 Citrix VDA servers per subscription
Impact: High Category: Governance
APRL GUID: c041d596-6c97-4c5f-b4b3-9cd37628f2e2
Description:
A Citrix Managed Azure subscription supports VMs with VDA for app/desktop delivery, excluding other machines like Cloud Connectors. When close to the limit, signaled by a dashboard notification, and with sufficient licenses, request another subscription. Can't exceed the given limits for catalogs.
Potential Benefits:
Avoids hitting limit, ensures reliability
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// Count VM instances with a tag that contains "Citrix VDA" and create output if that count is >2000 for each subscription.
// The Citrix published limit is 2500. This query runs an 80% check.
resources
| where type == 'microsoft.compute/virtualmachines'
| where tags contains 'Citrix VDA'
| summarize VMs=count() by subscriptionId
| where VMs > 2000
| join (resourcecontainers| where type =='microsoft.resources/subscriptions' | project subname=name, subscriptionId) on subscriptionId
| project recommendationId='c041d596-6c97-4c5f-b4b3-9cd37628f2e2', name= subname, id = subscriptionId, param1='Too many instances.', param2= VMs
Configure Service Health Alerts
Impact: High Category: Monitoring and Alerting
APRL GUID: 9729c89d-8118-41b4-a39b-e12468fa872b
Description:
Service health gives a personalized health view of Azure services and regions used, offering the best place for notifications on outages, planned maintenance, and health advisories by knowing the services used.
Potential Benefits:
Proactive outage and maintenance alerts
Learn More:
ARG Query:
Click the Azure Resource Graph tab to view the query
// Azure Resource Graph Query
// This resource graph query will return all subscriptions without Service Health alerts configured.
resourcecontainers
| where type == 'microsoft.resources/subscriptions'
| project subscriptionAlerts=tostring(id),name,tags
| join kind=leftouter (
resources
| where type == 'microsoft.insights/activitylogalerts' and properties.condition contains "ServiceHealth"
| extend subscriptions = properties.scopes
| project subscriptions
| mv-expand subscriptions
| project subscriptionAlerts = tostring(subscriptions)
) on subscriptionAlerts
| where isempty(subscriptionAlerts1)
| project-away subscriptionAlerts1
| project recommendationId = "9729c89d-8118-41b4-a39b-e12468fa872b",name,id=subscriptionAlerts,tags